_query.pm

package URI::_query;

use strict;
use warnings;

use URI ();
use URI::Escape qw(uri_unescape);

our $VERSION = '5.09';

sub query
{
    my $self = shift;
    $$self =~ m,^([^?\#]*)(?:\?([^\#]*))?(.*)$,s or die;

if (@_) {
	my $q = shift;
	$$self = $1;
	if (defined $q) {
	    $q =~ s/([^$URI::uric])/ URI::Escape::escape_char($1)/ego;
	    utf8::downgrade($q);
	    $$self .= "?$q";
	}
	$$self .= $3;
    }
    $2;
}

# Handle ...?foo=bar&bar=foo type of query
sub query_form {
    my $self = shift;
    my $old = $self->query;
    if (@_) {
        # Try to set query string
        my $delim;
        my $r = $_[0];
        if (ref($r) eq "ARRAY") {
            $delim = $_[1];
            @_ = @$r;
        }
        elsif (ref($r) eq "HASH") {
            $delim = $_[1];
            @_ = map { $_ => $r->{$_} } sort keys %$r;
        }
        $delim = pop if @_ % 2;

my @query;
        while (my($key,$vals) = splice(@_, 0, 2)) {
            $key = '' unless defined $key;
	    $key =~ s/([;\/?:@&=+,\$\[\]%])/ URI::Escape::escape_char($1)/eg;
	    $key =~ s/ /+/g;
	    $vals = [ref($vals) eq "ARRAY" ? @$vals : $vals];
            for my $val (@$vals) {
                $val = '' unless defined $val;
		$val =~ s/([;\/?:@&=+,\$\[\]%])/ URI::Escape::escape_char($1)/eg;
                $val =~ s/ /+/g;
                push(@query, "$key=$val");
            }
        }
        if (@query) {
            unless ($delim) {
                $delim = $1 if $old && $old =~ /([&;])/;
                $delim ||= $URI::DEFAULT_QUERY_FORM_DELIMITER || "&";
            }
            $self->query(join($delim, @query));
        }
        else {
            $self->query(undef);
        }
    }
    return if !defined($old) || !length($old) || !defined(wantarray);
    return unless $old =~ /=/; # not a form
    map { s/\+/ /g; uri_unescape($_) }
         map { /=/ ? split(/=/, $_, 2) : ($_ => '')} split(/[&;]/, $old);
}

# Handle ...?dog+bones type of query
sub query_keywords
{
    my $self = shift;
    my $old = $self->query;
    if (@_) {
        # Try to set query string
	my @copy = @_;
	@copy = @{$copy[0]} if @copy == 1 && ref($copy[0]) eq "ARRAY";
	for (@copy) { s/([;\/?:@&=+,\$\[\]%])/ URI::Escape::escape_char($1)/eg; }
	$self->query(@copy ? join('+', @copy) : undef);
    }
    return if !defined($old) || !defined(wantarray);
    return if $old =~ /=/;  # not keywords, but a form
    map { uri_unescape($_) } split(/\+/, $old, -1);
}

# Some URI::URL compatibility stuff
sub equery { goto &query }

docroot: /home/induvedam/public_html

curdir: /usr/share/perl5/URI

	.	4096
	..	4096
X	Escape.pm	7061
X	Heuristic.pm	6527
X	IRI.pm	794
X	QueryParam.pm	4861
X	Split.pm	2353
X	URL.pm	5487
X	WithBase.pm	3862
X	_foreign.pm	107
X	_generic.pm	5822
X	_idna.pm	2830
X	_ldap.pm	3249
X	_login.pm	231
X	_punycode.pm	5622
X	_query.pm	2531
X	_segment.pm	416
X	_server.pm	3724
X	_userpass.pm	1034
X	data.pm	3390
	file	108
X	file.pm	9761
X	ftp.pm	1056
X	gopher.pm	2428
X	http.pm	425
X	https.pm	144
X	ldap.pm	2924
X	ldapi.pm	440
X	ldaps.pm	144
X	mailto.pm	1276
X	mms.pm	125
X	news.pm	1454
X	nntp.pm	127
X	nntps.pm	144
X	pop.pm	1207
X	rlogin.pm	129
X	rsync.pm	207
X	rtsp.pm	125
X	rtspu.pm	126
X	sftp.pm	98
X	sip.pm	1695
X	sips.pm	143
X	snews.pm	172
X	ssh.pm	175
X	telnet.pm	128
X	tn3270.pm	128
	urn	35
X	urn.pm	2175